;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Author : $Author$
; Created By : Jon Green
; Created : Wed Nov 8 21:32:44 2006
; Last Modified : <061109.1859>
;
; Description : Override the C template.
; - Change the margin indent to 40 for comment align.
; - Extend Doxygen to highlight the parameter name not just the keyword.
;
; Notes : Copied and extended from hkc.emf
;
; Copyright (c) 2006 Jon Green.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Extend the indentation to allow for margin indentation.
!if &sin "d" .fhook-c.setup
    indent .hilight.c "m" 40
!endif

; Doxygen highlighting extensions. Highlights keywords in Doxygen
; Doxygen highlighting extensions. Highlights keywords in Doxygen
!if &and &sin "h" .fhook-c.setup &band .hilight.flags 0x02
    !if &sin "l" .fhook-c.setup
        ; Create a new doxygen parameter hilighting scheme
        !if &not &exi .hilight.pdoxygen
            set-variable .hilight.pdoxygen &pinc .hilight.next 1
            set-variable .hilight.pdoxygencpp &pinc .hilight.next 1
        !endif
        ;
        ; Special hilighting for a 'C' parameter - branch from the doxygen
        ; space into scheme for the parameter. Note that @param is defined
        ; after the generic '@' definitions.
        ; 
        ; Special for @param, @see, @retval   
        hilight .hilight.cdoxygen 0x80 "[\\\\@]param"  .hilight.pdoxygen .scheme.keyword
        hilight .hilight.cdoxygen 0x80 "[\\\\@]see"    .hilight.pdoxygen .scheme.keyword
        hilight .hilight.cdoxygen 0x80 "[\\\\@]retval" .hilight.pdoxygen .scheme.keyword
        ; Doxygen parameter hilighting space.
        0 hilight .hilight.pdoxygen 2 50 .scheme.error
        ; Hilight the next word and finish.
        hilight .hilight.pdoxygen 0x80 "\\w+" .hilight.cdoxygen .scheme.prepro
        ; We must return to C when we see the close of comment "*/"
        hilight .hilight.pdoxygen 0x80 "\\*/" .hilight.c .scheme.error
        ;
        ; Special hilighting for a 'C++' parameter - branch from the doxygen
        ; space into scheme for the parameter. Note that @param is defined
        ; after
        ; the generic '@' definitions.
        ; 
        ; Special for @param, @see, @retval   
        hilight .hilight.cdoxygencpp 0x80 "[\\\\@]param"  .hilight.pdoxygencpp .scheme.keyword
        hilight .hilight.cdoxygencpp 0x80 "[\\\\@]see"    .hilight.pdoxygencpp .scheme.keyword
        hilight .hilight.cdoxygencpp 0x80 "[\\\\@]retval" .hilight.pdoxygencpp .scheme.keyword
        ; Doxygen parameter hilighting space.
        0 hilight .hilight.pdoxygencpp 2 50 .scheme.error
        ; Hilight the next word and finish.
        hilight .hilight.pdoxygencpp 0x80 "\\w+" .hilight.cdoxygencpp .scheme.prepro
        ; We must return to C when we see the close of comment "*/"
        hilight .hilight.pdoxygencpp 0x80 "$" .hilight.c .scheme.error
    !endif
!endif