;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Author : $Author$
; Created By : Jon Green
; Created : Wed Nov 8 21:32:44 2006
; Last Modified : <061109.1859>
;
; Description : Override the C++ template.
; - Change the margin indent to 40 for comment align.
; - Extend Doxygen to highlight the parameter name not just the keyword.
;
; Notes : Copied and extended from hkcpp.emf
;
; Copyright (c) 2006 Jon Green.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Extend the indentation to allow for margin indentation.
!if &sin "d" .fhook-cpp.setup
    indent .hilight.cpp "m" 40
!endif

; Doxygen highlighting extensions. Highlights keywords in Doxygen
!if &and &sin "h" .fhook-cpp.setup &band .hilight.flags 0x02
    !if &sin "l" .fhook-cpp.setup
        ; Create a new doxygen parameter hilighting scheme
        !if &not &exi .hilight.pcppdoxygenc
            set-variable .hilight.pcppdoxygenc &pinc .hilight.next 1
            set-variable .hilight.pcppdoxygen  &pinc .hilight.next 1
        !endif
        ;
        ; Special hilighting for a 'C' parameter - branch from the doxygen
        ; space into scheme for the parameter. Note that @param is defined
        ; after the generic '@' definitions.
        ;
        ; Special for @param, @see, @retval
        hilight .hilight.cppdoxygenc 0x80 "[\\\\@]param"  .hilight.pcppdoxygenc .scheme.keyword
        hilight .hilight.cppdoxygenc 0x80 "[\\\\@]see"    .hilight.pcppdoxygenc .scheme.keyword
        hilight .hilight.cppdoxygenc 0x80 "[\\\\@]retval" .hilight.pcppdoxygenc .scheme.keyword
        ; Doxygen parameter hilighting space.
        0 hilight .hilight.pcppdoxygenc 2 50 .scheme.error
        ; Hilight the next word and finish.
        hilight .hilight.pcppdoxygenc 0x80 "\\w+" .hilight.cppdoxygenc .scheme.prepro
        ; We must return to C when we see the close of comment "*/"
        hilight .hilight.pcppdoxygenc 0x80 "\\*/" .hilight.cpp .scheme.error
        ;
        ; Special hilighting for a 'C++' parameter - branch from the doxygen
        ; space into scheme for the parameter. Note that @param is defined
        ; after
        ; the generic '@' definitions.
        ;
        ; Special for @param, @see, @retval
        hilight .hilight.cppdoxygen 0x80 "[\\\\@]param"  .hilight.pcppdoxygen .scheme.keyword
        hilight .hilight.cppdoxygen 0x80 "[\\\\@]see"    .hilight.pcppdoxygen .scheme.keyword
        hilight .hilight.cppdoxygen 0x80 "[\\\\@]retval" .hilight.pcppdoxygen .scheme.keyword
        ; Doxygen parameter hilighting space.
        0 hilight .hilight.pcppdoxygen 2 50 .scheme.error
        ; Hilight the next word and finish.
        hilight .hilight.pcppdoxygen 0x80 "\\w+" .hilight.cppdoxygen .scheme.prepro
        ; We must return to C when we see the close of comment "*/"
        hilight .hilight.pcppdoxygen 0x80 "$" .hilight.cpp .scheme.error
    !endif
!endif